xref: /llvm-project/llvm/test/Transforms/Coroutines/ex3.ll (revision 51d5d7bbae92493a5bfa7cc6b519de8a5bb32fdb) 
1; Third example from Doc/Coroutines.rst (two suspend points)
2; RUN: opt < %s -aa-pipeline=basic-aa -passes='default<O2>' -S | FileCheck %s
3
4define ptr @f(i32 %n) presplitcoroutine {
5entry:
6  %id = call token @llvm.coro.id(i32 0, ptr null, ptr null, ptr null)
7  %size = call i32 @llvm.coro.size.i32()
8  %need.dyn.alloc = call i1 @llvm.coro.alloc(token %id)
9  br i1 %need.dyn.alloc, label %dyn.alloc, label %coro.begin
10dyn.alloc:
11  %alloc = call ptr @malloc(i32 %size)
12  br label %coro.begin
13coro.begin:
14  %phi = phi ptr [ null, %entry ], [ %alloc, %dyn.alloc ]
15  %hdl = call noalias ptr @llvm.coro.begin(token %id, ptr %phi)
16  br label %loop
17loop:
18  %n.val = phi i32 [ %n, %coro.begin ], [ %inc, %loop.resume ]
19  call void @print(i32 %n.val) #4
20  %0 = call i8 @llvm.coro.suspend(token none, i1 false)
21  switch i8 %0, label %suspend [i8 0, label %loop.resume
22                                i8 1, label %cleanup]
23loop.resume:
24  %inc = add nsw i32 %n.val, 1
25  %sub = xor i32 %n.val, -1
26  call void @print(i32 %sub)
27  %1 = call i8 @llvm.coro.suspend(token none, i1 false)
28  switch i8 %1, label %suspend [i8 0, label %loop
29                                i8 1, label %cleanup]
30cleanup:
31  %mem = call ptr @llvm.coro.free(token %id, ptr %hdl)
32  call void @free(ptr %mem)
33  br label %suspend
34suspend:
35  call i1 @llvm.coro.end(ptr %hdl, i1 false, token none)
36  ret ptr %hdl
37}
38
39; CHECK-LABEL: @main
40define i32 @main() {
41entry:
42  %hdl = call ptr @f(i32 4)
43  call void @llvm.coro.resume(ptr %hdl)
44  call void @llvm.coro.resume(ptr %hdl)
45  %c = ptrtoint ptr %hdl to i64
46  %to = icmp eq i64 %c, 0
47  br i1 %to, label %return, label %destroy
48destroy:
49  call void @llvm.coro.destroy(ptr %hdl)
50  br label %return
51return:
52  ret i32 0
53; CHECK-NOT:  ptr @malloc
54; CHECK:      call void @print(i32 4)
55; CHECK-NEXT: call void @print(i32 -5)
56; CHECK-NEXT: call void @print(i32 5)
57; CHECK:      ret i32 0
58}
59
60declare ptr @malloc(i32)
61declare void @free(ptr)
62declare void @print(i32)
63
64declare token @llvm.coro.id(i32, ptr, ptr, ptr)
65declare i1 @llvm.coro.alloc(token)
66declare i32 @llvm.coro.size.i32()
67declare ptr @llvm.coro.begin(token, ptr)
68declare i8 @llvm.coro.suspend(token, i1)
69declare ptr @llvm.coro.free(token, ptr)
70declare i1 @llvm.coro.end(ptr, i1, token)
71
72declare void @llvm.coro.resume(ptr)
73declare void @llvm.coro.destroy(ptr)
74