xref: /llvm-project/llvm/test/DebugInfo/assignment-tracking/X86/nested-loop.ll (revision 30845e8ab46c416a2e333eb84239e9ec71e92617) 
1; RUN: llc %s -stop-after=finalize-isel -o - \
2; RUN: | FileCheck %s --implicit-check-not=DBG
3
4
5; RUN: llc --try-experimental-debuginfo-iterators %s -stop-after=finalize-isel -o - \
6; RUN: | FileCheck %s --implicit-check-not=DBG
7
8;; Test a variety of block inputs and lattice configurations for the assignment
9;; tracking analysis (debug-ata).
10
11;; The CFG looks like this:
12;;     entry
13;;     |
14;;     v
15;;     do.body <-----+
16;;     |             |
17;;     V             |
18;;     do.body1 <--+ |
19;;    / \          | |
20;;   /   \         | |
21;;  /     \        | |
22;; v       v       | |
23;; if.then if.else | |
24;;  \      /       | |
25;;   \    /        | |
26;;    \  /         | |
27;;     do.cond ----+ |
28;;     |             |
29;;     v             |
30;;     do.cond4 -----+
31;;     |
32;;     v
33;;     do.end6
34
35;;  Key
36;; ╔═════════════════════╦═══════════════════════════════════════════════════════════════════╗
37;; ║ thing               ║ meaning                                                           ║
38;; ╠═════════════════════╬═══════════════════════════════════════════════════════════════════╣
39;; ║ mem=<!n|phi>        ║ assignment of !n or phi to memory                                 ║
40;; ║ dbg=<!n|phi>        ║ assignment of !n or phi to source variable                        ║
41;; ║ phi                 ║ phi of assignments (operands not traked)*                         ║
42;; ║ loc=<val|mem|none>  ║ location to use is value (implicit location), stack home, or none ║
43;; ╚═════════════════════╩═══════════════════════════════════════════════════════════════════╝
44;;  (*) A phi in the def column represents an assignment made by an untagged store.
45;;
46;; Variable 'a' (!21)
47;; Check initial dbg and mem assignment values are propagated through all blocks.
48;; ╔═════════════╦══════════════════════════╦═════════════════╦══════════════════════════╗
49;; ║ block       ║ in                       ║ def             ║ out                      ║
50;; ╠═════════════╬══════════════════════════╬═════════════════╬══════════════════════════╣
51;; ║ entry       ║                          ║ mem=!63 dbg=!70 ║ mem=!63 dbg=!70 loc=val  ║
52;; ║ do.end6     ║ mem=!63 dbg=!70 loc=val  ║ mem=!63         ║ mem=!63 dbg=!63 loc=mem  ║
53;; ╚═════════════╩══════════════════════════╩═════════════════╩══════════════════════════╝
54;;
55;; Variable 'b' (!22)
56;; Check mem=dbg assignment on branch in nested loop causes a mem=phi (tested by looking
57;; for value-based DBG_VALUE in do.end6).
58;; ╔═════════════╦══════════════════════════╦═════════════════╦══════════════════════════╗
59;; ║ block       ║ in                       ║ def             ║ out                      ║
60;; ╠═════════════╬══════════════════════════╬═════════════════╬══════════════════════════╣
61;; ║ entry       ║                          ║ mem=!65 dbg=!71 ║ mem=!65 dbg=!71 loc=val  ║
62;; ║ if.then     ║ mem=phi dbg=phi loc=none ║ mem=!66 dbg=!66 ║ mem=!66 dbg=!66 loc=mem  ║
63;; ║ do.end6     ║ mem=phi dbg=phi loc=none ║ mem=!65         ║ mem=phi dbg=!65 loc=val  ║
64;; ╚═════════════╩══════════════════════════╩═════════════════╩══════════════════════════╝
65;;
66;; Variable 'c' (!67)
67;; Check initial dbg and mem assignment values are propagated through all blocks, with
68;; dbg defs with the inital assignment ID put in do.cond and do.end6 (variable is always
69;; in memory).
70;; ╔═════════════╦══════════════════════════╦═════════════════╦══════════════════════════╗
71;; ║ block       ║ in                       ║ def             ║ out                      ║
72;; ╠═════════════╬══════════════════════════╬═════════════════╬══════════════════════════╣
73;; ║ entry       ║                          ║ mem=!69 dbg=!69 ║ mem=!69 dbg=!69 loc=mem  ║
74;; ║ do.cond     ║ mem=!69 dbg=!69 loc=mem  ║         dbg=!69 ║ mem=!69 dbg=!69 loc=mem  ║
75;; ║ do.end6     ║ mem=!69 dbg=!69 loc=mem  ║         dbg=!69 ║ mem=!69 dbg=!69 loc=mem  ║
76;; ╚═════════════╩══════════════════════════╩═════════════════╩══════════════════════════╝
77;;
78;; Variable 'd' (!72)
79;; Same as above, except the dbg def in do.cond has been swapped for a dbg=mem def (with
80;; the initial assignment ID) and has been moved to if.else.
81;; ╔═════════════╦══════════════════════════╦═════════════════╦══════════════════════════╗
82;; ║ block       ║ in                       ║ def             ║ out                      ║
83;; ╠═════════════╬══════════════════════════╬═════════════════╬══════════════════════════╣
84;; ║ entry       ║                          ║ mem=!74 dbg=!74 ║ mem=!74 dbg=!74 loc=mem  ║
85;; ║ if.else     ║ mem=!74 dbg=!74 loc=mem  ║ mem=!74 dbg=!74 ║ mem=!74 dbg=!74 loc=mem  ║
86;; ║ do.end6     ║ mem=!74 dbg=!74 loc=mem  ║         dbg=!74 ║ mem=!74 dbg=!74 loc=mem  ║
87;; ╚═════════════╩══════════════════════════╩═════════════════╩══════════════════════════╝
88;;
89;; Variable 'e' (!75)
90;; mem defs in entry, if.then and if.else with same ID (!77). Check these join correct
91;; (tested using the dbg defs of the same ID - the memory location is valid at each of
92;; these with that ID).
93;; ╔═════════════╦══════════════════════════╦═════════════════╦══════════════════════════╗
94;; ║ block       ║ in                       ║ def             ║ out                      ║
95;; ╠═════════════╬══════════════════════════╬═════════════════╬══════════════════════════╣
96;; ║ entry       ║                          ║ mem=!77 dbg=!78 ║ mem=!77 dbg=!78 loc=val  ║
97;; ║ do.body     ║ mem=!77 dbg=phi loc=none ║         dbg=!77 ║ mem=!77 dbg=!77 loc=mem  ║
98;; ║ do.body1    ║ mem=!77 dbg=!77 loc=mem  ║         dbg=!77 ║ mem=!77 dbg=!77 loc=mem  ║
99;; ║ if.then     ║ mem=!77 dbg=!77 loc=mem  ║ mem=!77         ║ mem=!77 dbg=!77 loc=mem  ║
100;; ║ if.else     ║ mem=!77 dbg=!77 loc=mem  ║ mem=!77         ║ mem=!77 dbg=!77 loc=mem  ║
101;; ╚═════════════╩══════════════════════════╩═════════════════╩══════════════════════════╝
102;;
103;; Variable 'f' (!79)
104;; mem def in entry and an untagged store in if.else (results in mem=phi, dbg=phi defs).
105;; Use dbg defs in do.body, do.body1, do.cond and do.end6 to check the phi-ness
106;; has been propagated (the memory loc at each is not a valid location). Check the memory
107;; loc is used in if.else after the untagged store.
108;; ╔═════════════╦══════════════════════════╦═════════════════╦══════════════════════════╗
109;; ║ block       ║ in                       ║ def             ║ out                      ║
110;; ╠═════════════╬══════════════════════════╬═════════════════╬══════════════════════════╣
111;; ║ entry       ║                          ║ mem=!81 dbg=!81 ║ mem=!81 dbg=!81 loc=mem  ║
112;; ║ do.body     ║ mem=phi dbg=phi loc=none ║         dbg=!81 ║ mem=phi dbg=!81 loc=val  ║
113;; ║ do.body1    ║ mem=phi dbg=phi loc=none ║         dbg=!81 ║ mem=phi dbg=!81 loc=val  ║
114;; ║ if.else     ║ mem=phi dbg=phi loc=none ║ mem=phi dbg=phi ║ mem=phi dbg=phi loc=mem  ║
115;; ║ do.cond     ║ mem=phi dbg=phi loc=none ║         dbg=!81 ║ mem=phi dbg=!81 loc=val  ║
116;; ║ do.end6     ║ mem=phi dbg=!81 loc=val  ║         dbg=!81 ║ mem=!69 dbg=!81 loc=val  ║
117;; ╚═════════════╩══════════════════════════╩═════════════════╩══════════════════════════╝
118;;
119;; Variable 'g' (!82)
120;; Check that joining loc=none with anything else results in loc=none. The out-loc of
121;; entry is set up to be loc=none by following an untagged store with a tagged store,
122;; with the linked dbg.assign in another block. The dbg.assign is in do.body - it follows
123;; another store linked to it. Importantly, there are other instructions wedged between
124;; them, which is how we test that the in-loc is loc=none. The result of encountering
125;; a tagged store while the loc=none is to emit nothing. Thus, we check that no location
126;; def is emitted in do.body until the dbg.assign is encountered (after the load that was
127;; wedged between the store and intrinsic).
128;; ╔═════════════╦══════════════════════════╦═════════════════╦══════════════════════════╗
129;; ║ block       ║ in                       ║ def             ║ out                      ║
130;; ╠═════════════╬══════════════════════════╬═════════════════╬══════════════════════════╣
131;; ║ entry       ║                          ║ mem=phi dbg=phi ║ mem=phi dbg=phi loc=none ║
132;; ║ do.body     ║ mem=phi dbg=phi loc=none ║ mem=!84 dbg=!84 ║ mem=!84 dbg=!84 loc=mem  ║
133;; ╚═════════════╩══════════════════════════╩═════════════════╩══════════════════════════╝
134
135; CHECK-DAG: ![[a:[0-9]+]] = !DILocalVariable(name: "a",
136; CHECK-DAG: ![[b:[0-9]+]] = !DILocalVariable(name: "b",
137; CHECK-DAG: ![[c:[0-9]+]] = !DILocalVariable(name: "c",
138; CHECK-DAG: ![[d:[0-9]+]] = !DILocalVariable(name: "d",
139; CHECK-DAG: ![[e:[0-9]+]] = !DILocalVariable(name: "e",
140; CHECK-DAG: ![[f:[0-9]+]] = !DILocalVariable(name: "f",
141; CHECK-DAG: ![[g:[0-9]+]] = !DILocalVariable(name: "g",
142
143;; Variables 'c' (!67) and 'd' (!72) are always stack-homed.
144; CHECK:      - { id: 2, name: c.addr, type: default, offset: 0, size: 4, alignment: 4,
145; CHECK-NEXT:     stack-id: default, callee-saved-register: '', callee-saved-restored: true,
146; CHECK-NEXT:     debug-info-variable: '![[c]]', debug-info-expression: '!DIExpression()',
147; CHECK:      - { id: 3, name: d.addr, type: default, offset: 0, size: 4, alignment: 4,
148; CHECK-NEXT:     stack-id: default, callee-saved-register: '', callee-saved-restored: true,
149; CHECK-NEXT:     debug-info-variable: '![[d]]', debug-info-expression: '!DIExpression()',
150
151source_filename = "test.cpp"
152target datalayout = "e-m:e-p270:32:32-p271:32:32-p272:64:64-i64:64-f80:128-n8:16:32:64-S128"
153target triple = "x86_64-unknown-linux-gnu"
154
155@g_a = dso_local local_unnamed_addr global i32 0, align 4, !dbg !0
156@g_b = dso_local local_unnamed_addr global i32 0, align 4, !dbg !5
157@g_c = dso_local local_unnamed_addr global i32 0, align 4, !dbg !8
158
159define dso_local noundef i32 @_Z3funii(i32 noundef %a, i32 noundef %b) local_unnamed_addr #0 !dbg !17 {
160entry:
161  %a.addr = alloca i32, align 4, !DIAssignID !58 ; VAR:a
162  call void @llvm.dbg.assign(metadata i1 undef, metadata !21, metadata !DIExpression(), metadata !58, metadata ptr %a.addr, metadata !DIExpression()), !dbg !27 ; VAR:a
163  %b.addr = alloca i32, align 4, !DIAssignID !64 ; VAR:b
164  call void @llvm.dbg.assign(metadata i1 undef, metadata !22, metadata !DIExpression(), metadata !64, metadata ptr %b.addr, metadata !DIExpression()), !dbg !27 ; VAR:b
165  %c.addr = alloca i32, align 4, !DIAssignID !68 ; VAR:c
166  call void @llvm.dbg.assign(metadata i1 undef, metadata !67, metadata !DIExpression(), metadata !68, metadata ptr %c.addr, metadata !DIExpression()), !dbg !27 ; VAR:c
167  %d.addr = alloca i32, align 4, !DIAssignID !73 ; VAR:d
168  call void @llvm.dbg.assign(metadata i1 undef, metadata !72, metadata !DIExpression(), metadata !73, metadata ptr %d.addr, metadata !DIExpression()), !dbg !27 ; VAR:d
169  %e.addr = alloca i32, align 4, !DIAssignID !76 ; VAR:e
170  call void @llvm.dbg.assign(metadata i1 undef, metadata !75, metadata !DIExpression(), metadata !76, metadata ptr %e.addr, metadata !DIExpression()), !dbg !27 ; VAR:e
171  %f.addr = alloca i32, align 4, !DIAssignID !80 ; VAR:f
172  call void @llvm.dbg.assign(metadata i1 undef, metadata !79, metadata !DIExpression(), metadata !80, metadata ptr %f.addr, metadata !DIExpression()), !dbg !27 ; VAR:f
173  %g.addr = alloca i32, align 4, !DIAssignID !83 ; VAR:g
174  call void @llvm.dbg.assign(metadata i1 undef, metadata !82, metadata !DIExpression(), metadata !83, metadata ptr %g.addr, metadata !DIExpression()), !dbg !27 ; VAR:g
175  store i32 1, ptr %a.addr, !DIAssignID !70 ; VAR:a
176  call void @llvm.dbg.assign(metadata i32 1, metadata !21, metadata !DIExpression(), metadata !70, metadata ptr %a.addr, metadata !DIExpression()), !dbg !27 ; VAR:a
177  store i32 2, ptr %b.addr, !DIAssignID !71 ; VAR:b
178  call void @llvm.dbg.assign(metadata i32 2, metadata !22, metadata !DIExpression(), metadata !71, metadata ptr %b.addr, metadata !DIExpression()), !dbg !27 ; VAR:b
179  store i32 12, ptr %g.addr ; VAR:g
180  store i32 9, ptr %e.addr, !DIAssignID !78 ; VAR:e
181  call void @llvm.dbg.assign(metadata i32 9, metadata !75, metadata !DIExpression(), metadata !78, metadata ptr %e.addr, metadata !DIExpression()), !dbg !27 ; VAR:c
182  store i32 3, ptr %a.addr, !DIAssignID !63 ; VAR:a
183  store i32 4, ptr %b.addr, !DIAssignID !65 ; VAR:b
184  store i32 5, ptr %c.addr, !DIAssignID !69 ; VAR:c
185  call void @llvm.dbg.assign(metadata i32 5, metadata !67, metadata !DIExpression(), metadata !69, metadata ptr %c.addr, metadata !DIExpression()), !dbg !27 ; VAR:c
186  store i32 6, ptr %d.addr, !DIAssignID !74 ; VAR:d
187  call void @llvm.dbg.assign(metadata i32 6, metadata !72, metadata !DIExpression(), metadata !74, metadata ptr %d.addr, metadata !DIExpression()), !dbg !27 ; VAR:d
188  store i32 8, ptr %e.addr, !DIAssignID !77 ; VAR:e
189  store i32 13, ptr %g.addr, !DIAssignID !84 ; VAR:g
190  store i32 11, ptr %f.addr, !DIAssignID !81 ; VAR:f
191  call void @llvm.dbg.assign(metadata i32 11, metadata !79, metadata !DIExpression(), metadata !81, metadata ptr %f.addr, metadata !DIExpression()), !dbg !27 ; VAR:f
192  br label %do.body, !dbg !24
193; CHECK-LABEL: bb.0.entry:
194; CHECK-NEXT: successors
195; CHECK-NEXT: {{^ *$}}
196; CHECK-NEXT:    DBG_VALUE %stack.0.a.addr, $noreg, ![[a]], !DIExpression(DW_OP_deref)
197; CHECK-NEXT:    DBG_VALUE %stack.1.b.addr, $noreg, ![[b]], !DIExpression(DW_OP_deref)
198; CHECK-NEXT:    DBG_VALUE %stack.4.e.addr, $noreg, ![[e]], !DIExpression(DW_OP_deref)
199; CHECK-NEXT:    DBG_VALUE %stack.5.f.addr, $noreg, ![[f]], !DIExpression(DW_OP_deref)
200; CHECK-NEXT:    DBG_VALUE %stack.6.g.addr, $noreg, ![[g]], !DIExpression(DW_OP_deref)
201; CHECK-NEXT:    MOV32mi %stack.0.a.addr, 1, $noreg, 0, $noreg, 3
202; CHECK-NEXT:    DBG_VALUE 1, $noreg, ![[a]], !DIExpression()
203; CHECK-NEXT:    MOV32mi %stack.1.b.addr, 1, $noreg, 0, $noreg, 4
204; CHECK-NEXT:    DBG_VALUE 2, $noreg, ![[b]], !DIExpression()
205; CHECK-NEXT:    MOV32mi %stack.2.c.addr, 1, $noreg, 0, $noreg, 5
206; CHECK-NEXT:    MOV32mi %stack.3.d.addr, 1, $noreg, 0, $noreg, 6
207; CHECK-NEXT:    MOV32mi %stack.4.e.addr, 1, $noreg, 0, $noreg, 8
208; CHECK-NEXT:    DBG_VALUE 9, $noreg, ![[e]], !DIExpression()
209; CHECK-NEXT:    MOV32mi %stack.6.g.addr, 1, $noreg, 0, $noreg, 13
210; CHECK-NEXT:    DBG_VALUE $noreg, $noreg, ![[g]], !DIExpression()
211; CHECK-NEXT:    MOV32mi %stack.5.f.addr, 1, $noreg, 0, $noreg, 11
212; CHECK-NEXT: {{^ *$}}
213
214do.body:                                          ; preds = %do.cond4, %entry
215  call void @llvm.dbg.assign(metadata i32 8, metadata !75, metadata !DIExpression(), metadata !77, metadata ptr %e.addr, metadata !DIExpression()), !dbg !27 ; VAR:e
216  call void @llvm.dbg.assign(metadata i32 11, metadata !79, metadata !DIExpression(), metadata !81, metadata ptr %f.addr, metadata !DIExpression()), !dbg !27 ; VAR:f
217  store i32 13, ptr %g.addr, !DIAssignID !84 ; VAR:g
218  %.pre10 = load i32, ptr @g_a, align 4, !dbg !27
219  call void @llvm.dbg.assign(metadata i32 11, metadata !82, metadata !DIExpression(), metadata !84, metadata ptr %g.addr, metadata !DIExpression()), !dbg !27 ; VAR:g
220  br label %do.body1, !dbg !34
221; CHECK-LABEL: bb.1.do.body:
222; CHECK-NEXT: successors
223; CHECK-NEXT: {{^ *$}}
224; CHECK-NEXT:    DBG_VALUE %stack.4.e.addr, $noreg, ![[e]], !DIExpression(DW_OP_deref)
225; CHECK-NEXT:    DBG_VALUE 11, $noreg, ![[f]], !DIExpression()
226; CHECK-NEXT:    MOV32mi %stack.6.g.addr, 1, $noreg, 0, $noreg, 13
227; CHECK-NEXT:    %0:gr32 = MOV32rm $rip, 1, $noreg, @g_a, $noreg
228; CHECK-NEXT:    DBG_VALUE %stack.6.g.addr, $noreg, ![[g]], !DIExpression(DW_OP_deref)
229; CHECK-NEXT: {{^ *$}}
230
231do.body1:                                         ; preds = %do.cond, %do.body
232  %0 = phi i32 [ %.pre10, %do.body ], [ %1, %do.cond ], !dbg !27
233  call void @llvm.dbg.assign(metadata i32 8, metadata !75, metadata !DIExpression(), metadata !77, metadata ptr %e.addr, metadata !DIExpression()), !dbg !27 ; VAR:e
234  call void @llvm.dbg.assign(metadata i32 11, metadata !79, metadata !DIExpression(), metadata !81, metadata ptr %f.addr, metadata !DIExpression()), !dbg !27 ; VAR:f
235  %tobool.not = icmp eq i32 %0, 0, !dbg !27
236  br i1 %tobool.not, label %if.else, label %if.then, !dbg !35
237; CHECK-LABEL: bb.2.do.body1:
238; CHECK-NEXT: successors
239; CHECK-NEXT: {{^ *$}}
240; CHECK:         DBG_VALUE %stack.4.e.addr, $noreg, ![[e]], !DIExpression(DW_OP_deref)
241; CHECK-NEXT:    DBG_VALUE 11, $noreg, ![[f]], !DIExpression()
242; CHECK:         JMP_1
243; CHECK-NEXT: {{^ *$}}
244
245if.then:                                          ; preds = %do.body1
246  %.pre = load i32, ptr @g_a, align 4, !dbg !27
247  store i32 %.pre, ptr %b.addr, !DIAssignID !66 ; VAR:b
248  call void @llvm.dbg.assign(metadata i32 %.pre, metadata !22, metadata !DIExpression(), metadata !66, metadata ptr %b.addr, metadata !DIExpression()), !dbg !27 ; VAR:b
249  store i32 8, ptr %e.addr, !DIAssignID !77 ; VAR:e
250  br label %do.cond, !dbg !39
251; CHECK-LABEL: bb.3.if.then:
252; CHECK-NEXT: successors
253; CHECK-NEXT: {{^ *$}}
254; CHECK-NEXT:    %5:gr32 = MOV32rm
255; CHECK-NEXT:    MOV32mr %stack.1.b.addr, 1, $noreg, 0, $noreg, killed %5
256; CHECK-NEXT:    DBG_VALUE %stack.1.b.addr, $noreg, ![[b]], !DIExpression(DW_OP_deref
257; CHECK-NEXT:    MOV32mi %stack.4.e.addr, 1, $noreg, 0, $noreg, 8
258; CHECK-NEXT:    DBG_VALUE %stack.4.e.addr, $noreg, ![[e]], !DIExpression(DW_OP_deref)
259; CHECK-NEXT:    JMP_1 %bb.5
260; CHECK-NEXT: {{^ *$}}
261
262if.else:                                          ; preds = %do.body1
263  store i32 6, ptr %d.addr, !DIAssignID !74 ; VAR:d
264  call void @llvm.dbg.assign(metadata i32 6, metadata !72, metadata !DIExpression(), metadata !74, metadata ptr %d.addr, metadata !DIExpression()), !dbg !27 ; VAR:d
265  store i32 8, ptr %e.addr, !DIAssignID !77 ; VAR:e
266  store i32 10, ptr %f.addr ; VAR:f
267  br label %do.cond
268; CHECK-LABEL: bb.4.if.else:
269; CHECK-NEXT: successors
270; CHECK-NEXT: {{^ *$}}
271; CHECK-NEXT:    MOV32mi %stack.3.d.addr, 1, $noreg, 0, $noreg, 6
272; CHECK-NEXT:    MOV32mi %stack.4.e.addr, 1, $noreg, 0, $noreg, 8
273; CHECK-NEXT:    DBG_VALUE %stack.4.e.addr, $noreg, ![[e]], !DIExpression(DW_OP_deref)
274; CHECK-NEXT:    MOV32mi %stack.5.f.addr, 1, $noreg, 0, $noreg, 10
275; CHECK-NEXT:    DBG_VALUE %stack.5.f.addr, $noreg, ![[f]], !DIExpression(DW_OP_deref)
276; CHECK-NEXT: {{^ *$}}
277
278do.cond:                                          ; preds = %if.then, %if.else
279  call void @llvm.dbg.assign(metadata i1 undef, metadata !67, metadata !DIExpression(), metadata !69, metadata ptr %c.addr, metadata !DIExpression()), !dbg !27 ; VAR:c
280  call void @llvm.dbg.assign(metadata i32 11, metadata !79, metadata !DIExpression(), metadata !81, metadata ptr %f.addr, metadata !DIExpression()), !dbg !27 ; VAR:f
281  %1 = load i32, ptr @g_b, align 4, !dbg !43
282  %tobool3.not = icmp eq i32 %1, 0, !dbg !43
283  br i1 %tobool3.not, label %do.cond4, label %do.body1, !dbg !44, !llvm.loop !45
284; CHECK-LABEL: bb.5.do.cond:
285; CHECK-NEXT: successors
286; CHECK-NEXT: {{^ *$}}
287; CHECK-NEXT:    DBG_VALUE 11, $noreg, ![[f]], !DIExpression()
288; CHECK:      {{^ *$}}
289
290do.cond4:                                         ; preds = %do.cond
291  %2 = load i32, ptr @g_c, align 4, !dbg !48
292  %tobool5.not = icmp eq i32 %2, 0, !dbg !48
293  br i1 %tobool5.not, label %do.end6, label %do.body, !dbg !49, !llvm.loop !50
294; CHECK-LABEL: bb.6.do.cond4:
295; CHECK-NEXT: successors
296; CHECK-NEXT: {{^ *$}}
297; CHECK-NOT:     DBG
298; CHECK: {{^ *$}}
299
300do.end6:                                          ; preds = %do.cond4
301  call void @llvm.dbg.assign(metadata i32 3, metadata !21, metadata !DIExpression(), metadata !63, metadata ptr %a.addr, metadata !DIExpression()), !dbg !27; VAR:a
302  call void @llvm.dbg.assign(metadata i32 4, metadata !22, metadata !DIExpression(), metadata !65, metadata ptr %b.addr, metadata !DIExpression()), !dbg !27 ; VAR:b
303  call void @llvm.dbg.assign(metadata i1 undef, metadata !67, metadata !DIExpression(), metadata !69, metadata ptr %c.addr, metadata !DIExpression()), !dbg !27 ; VAR:c
304  call void @llvm.dbg.assign(metadata i32 6, metadata !72, metadata !DIExpression(), metadata !74, metadata ptr %d.addr, metadata !DIExpression()), !dbg !27 ; VAR:d
305  call void @llvm.dbg.assign(metadata i32 11, metadata !79, metadata !DIExpression(), metadata !81, metadata ptr %f.addr, metadata !DIExpression()), !dbg !27 ; VAR:f
306  ret i32 0, !dbg !53
307; CHECK-LABEL: bb.7.do.end6:
308; CHECK-NEXT:    DBG_VALUE %stack.0.a.addr, $noreg, ![[a]], !DIExpression(DW_OP_deref)
309; CHECK-NEXT:    DBG_VALUE 4, $noreg, ![[b]], !DIExpression()
310; CHECK-NEXT:    DBG_VALUE 11, $noreg, ![[f]], !DIExpression()
311}
312
313declare !dbg !54 void @_Z4calli(i32 noundef) local_unnamed_addr #1
314declare void @llvm.dbg.declare(metadata, metadata, metadata)
315declare void @llvm.dbg.value(metadata, metadata, metadata)
316declare void @llvm.dbg.assign(metadata, metadata, metadata, metadata, metadata, metadata)
317
318!llvm.dbg.cu = !{!2}
319!llvm.module.flags = !{!10, !11, !12, !13, !14, !15, !1000}
320!llvm.ident = !{!16}
321
322!0 = !DIGlobalVariableExpression(var: !1, expr: !DIExpression())
323!1 = distinct !DIGlobalVariable(name: "g_a", scope: !2, file: !3, line: 1, type: !7, isLocal: false, isDefinition: true)
324!2 = distinct !DICompileUnit(language: DW_LANG_C_plus_plus_14, file: !3, producer: "clang version 16.0.0", isOptimized: true, runtimeVersion: 0, emissionKind: FullDebug, globals: !4, splitDebugInlining: false, nameTableKind: None)
325!3 = !DIFile(filename: "test.cpp", directory: "/")
326!4 = !{!0, !5, !8}
327!5 = !DIGlobalVariableExpression(var: !6, expr: !DIExpression())
328!6 = distinct !DIGlobalVariable(name: "g_b", scope: !2, file: !3, line: 1, type: !7, isLocal: false, isDefinition: true)
329!7 = !DIBasicType(name: "int", size: 32, encoding: DW_ATE_signed)
330!8 = !DIGlobalVariableExpression(var: !9, expr: !DIExpression())
331!9 = distinct !DIGlobalVariable(name: "g_c", scope: !2, file: !3, line: 1, type: !7, isLocal: false, isDefinition: true)
332!10 = !{i32 7, !"Dwarf Version", i32 5}
333!11 = !{i32 2, !"Debug Info Version", i32 3}
334!12 = !{i32 1, !"wchar_size", i32 4}
335!13 = !{i32 8, !"PIC Level", i32 2}
336!14 = !{i32 7, !"PIE Level", i32 2}
337!15 = !{i32 7, !"uwtable", i32 2}
338!16 = !{!"clang version 16.0.0"}
339!17 = distinct !DISubprogram(name: "fun", linkageName: "_Z3funii", scope: !3, file: !3, line: 3, type: !18, scopeLine: 3, flags: DIFlagPrototyped | DIFlagAllCallsDescribed, spFlags: DISPFlagDefinition | DISPFlagOptimized, unit: !2, retainedNodes: !20)
340!18 = !DISubroutineType(types: !19)
341!19 = !{!7, !7, !7}
342!20 = !{!21, !22}
343!21 = !DILocalVariable(name: "a", arg: 1, scope: !17, file: !3, line: 3, type: !7)
344!22 = !DILocalVariable(name: "b", arg: 2, scope: !17, file: !3, line: 3, type: !7)
345!23 = !DILocation(line: 0, scope: !17)
346!24 = !DILocation(line: 4, column: 3, scope: !17)
347!25 = !DILocation(line: 5, column: 5, scope: !26)
348!26 = distinct !DILexicalBlock(scope: !17, file: !3, line: 4, column: 6)
349!27 = !DILocation(line: 7, column: 11, scope: !28)
350!28 = distinct !DILexicalBlock(scope: !29, file: !3, line: 7, column: 11)
351!29 = distinct !DILexicalBlock(scope: !26, file: !3, line: 6, column: 8)
352!34 = !DILocation(line: 6, column: 5, scope: !26)
353!35 = !DILocation(line: 7, column: 11, scope: !29)
354!36 = !DILocation(line: 8, column: 11, scope: !37)
355!37 = distinct !DILexicalBlock(scope: !28, file: !3, line: 7, column: 16)
356!38 = !DILocation(line: 9, column: 9, scope: !37)
357!39 = !DILocation(line: 10, column: 7, scope: !37)
358!40 = !DILocation(line: 11, column: 11, scope: !41)
359!41 = distinct !DILexicalBlock(scope: !28, file: !3, line: 10, column: 14)
360!42 = !DILocation(line: 0, scope: !28)
361!43 = !DILocation(line: 13, column: 14, scope: !26)
362!44 = !DILocation(line: 13, column: 5, scope: !29)
363!45 = distinct !{!45, !34, !46, !47}
364!46 = !DILocation(line: 13, column: 17, scope: !26)
365!47 = !{!"llvm.loop.mustprogress"}
366!48 = !DILocation(line: 14, column: 12, scope: !17)
367!49 = !DILocation(line: 14, column: 3, scope: !26)
368!50 = distinct !{!50, !24, !51, !47}
369!51 = !DILocation(line: 14, column: 15, scope: !17)
370!52 = !DILocation(line: 15, column: 12, scope: !17)
371!53 = !DILocation(line: 15, column: 3, scope: !17)
372!54 = !DISubprogram(name: "call", linkageName: "_Z4calli", scope: !3, file: !3, line: 2, type: !55, flags: DIFlagPrototyped, spFlags: DISPFlagOptimized, retainedNodes: !57)
373!55 = !DISubroutineType(types: !56)
374!56 = !{null, !7}
375!57 = !{}
376!58 = distinct !DIAssignID()
377!59 = !DILocalVariable(name: "Arr", scope: !17, file: !3, line: 4, type: !60)
378!60 = !DICompositeType(tag: DW_TAG_array_type, baseType: !7, size: 96, elements: !61)
379!61 = !{!62}
380!62 = !DISubrange(count: 3)
381!63 = distinct !DIAssignID()
382!64 = distinct !DIAssignID()
383!65 = distinct !DIAssignID()
384!66 = distinct !DIAssignID()
385!67 = !DILocalVariable(name: "c", scope: !17, file: !3, line: 3, type: !7)
386!68 = distinct !DIAssignID()
387!69 = distinct !DIAssignID()
388!70 = distinct !DIAssignID()
389!71 = distinct !DIAssignID()
390!72 = !DILocalVariable(name: "d", scope: !17, file: !3, line: 3, type: !7)
391!73 = distinct !DIAssignID()
392!74 = distinct !DIAssignID()
393!75 = !DILocalVariable(name: "e", scope: !17, file: !3, line: 3, type: !7)
394!76 = distinct !DIAssignID()
395!77 = distinct !DIAssignID()
396!78 = distinct !DIAssignID()
397!79 = !DILocalVariable(name: "f", scope: !17, file: !3, line: 3, type: !7)
398!80 = distinct !DIAssignID()
399!81 = distinct !DIAssignID()
400!82 = !DILocalVariable(name: "g", scope: !17, file: !3, line: 3, type: !7)
401!83 = distinct !DIAssignID()
402!84 = distinct !DIAssignID()
403!1000 = !{i32 7, !"debug-info-assignment-tracking", i1 true}
404