xref: /netbsd-src/sys/arch/riscv/conf/kern.ldscript (revision 7330f729ccf0bd976a06f95fad452fe774fc7fd1) 
1OUTPUT_ARCH(riscv)
2ENTRY(start)
3
4__PAGE_SIZE = 0x1000 ;
5__LARGE_PAGE_SIZE = 0x200000 ;
6
7SECTIONS
8{
9	.text : AT (ADDR(.text) & 0x0fffffff)
10	{
11		*(.text)
12		*(.text.*)
13		*(.stub)
14	}
15	_etext = . ;
16	PROVIDE (etext = .);
17
18	. = ALIGN(__LARGE_PAGE_SIZE);
19
20	__rodata_start = . ;
21	.rodata :
22	{
23		*(.rodata)
24		*(.rodata.*)
25		*(.srodata)
26		*(.srodata.*)
27	}
28
29	. = ALIGN(__LARGE_PAGE_SIZE);
30
31	__data_start = . ;
32	.data :
33	{
34		*(.data)
35		*(.sdata)
36		*(.sdata.*)
37	}
38	_edata = . ;
39	PROVIDE (edata = .) ;
40
41	__bss_start = .;
42	.bss :
43	{
44		*(.bss)
45		*(.bss.*)
46		*(.sbss)
47		*(.sbss.*)
48		*(COMMON)
49		. = ALIGN(__LARGE_PAGE_SIZE);
50	}
51
52	. = ALIGN(__PAGE_SIZE);
53
54	/* End of the kernel image */
55	__kernel_end = . ;
56
57	_end = . ;
58	PROVIDE (end = .) ;
59	.note.netbsd.ident :
60	{
61		KEEP(*(.note.netbsd.ident));
62	}
63}
64