xref: /netbsd-src/sys/arch/i386/conf/kern.ldscript.Xen (revision b83ebeba7f767758d2778bb0f9d7a76534253621) 
1/*	$NetBSD: kern.ldscript.Xen,v 1.13 2016/08/02 14:03:34 maxv Exp $	*/
2
3#include "assym.h"
4
5__PAGE_SIZE = 0x1000 ;
6
7SECTIONS
8{
9	.text :
10	{
11		*(.text)
12		*(.text.*)
13		*(.stub)
14	}
15	_etext = . ;
16	PROVIDE (etext = .) ;
17
18	. = ALIGN(__PAGE_SIZE);
19
20	__rodata_start = . ;
21	.rodata :
22	{
23		*(.rodata)
24		*(.rodata.*)
25	}
26
27	. = ALIGN(__PAGE_SIZE);
28
29	__data_start = . ;
30	.data :
31	{
32		*(.data)
33	}
34
35	. = ALIGN(COHERENCY_UNIT);
36	.data.cacheline_aligned :
37	{
38		*(.data.cacheline_aligned)
39	}
40	. = ALIGN(COHERENCY_UNIT);
41	.data.read_mostly :
42	{
43		*(.data.read_mostly)
44	}
45	. = ALIGN(COHERENCY_UNIT);
46
47	_edata = . ;
48	PROVIDE (edata = .) ;
49	__bss_start = . ;
50	.bss :
51	{
52		*(.bss)
53		*(.bss.*)
54		*(COMMON)
55		. = ALIGN(32 / 8);
56	}
57
58	. = ALIGN(__PAGE_SIZE);
59
60	/* End of the kernel image */
61	__kernel_end = . ;
62
63	_end = . ;
64	PROVIDE (end = .) ;
65	.note.netbsd.ident :
66	{
67		KEEP(*(.note.netbsd.ident));
68	}
69}
70
71SECTIONS
72{
73	.text :
74	AT (ADDR(.text))
75	{
76		*(.text)
77	} = 0
78}
79