xref: /minix3/sys/external/bsd/compiler_rt/dist/lib/builtins/arm/divmodsi4.S (revision 0a6a1f1d05b60e214de2f05a7310ddd1f0e590e7)
1/*===-- divmodsi4.S - 32-bit signed integer divide and modulus ------------===//
2 *
3 *                     The LLVM Compiler Infrastructure
4 *
5 * This file is dual licensed under the MIT and the University of Illinois Open
6 * Source Licenses. See LICENSE.TXT for details.
7 *
8 *===----------------------------------------------------------------------===//
9 *
10 * This file implements the __divmodsi4 (32-bit signed integer divide and
11 * modulus) function for the ARM architecture.  A naive digit-by-digit
12 * computation is employed for simplicity.
13 *
14 *===----------------------------------------------------------------------===*/
15
16#include "../assembly.h"
17
18#define ESTABLISH_FRAME    \
19    push   {r4-r7, lr}   ;\
20    add     r7,     sp, #12
21#define CLEAR_FRAME_AND_RETURN \
22    pop    {r4-r7, pc}
23
24	.syntax unified
25	.text
26#if __ARM_ARCH_ISA_THUMB == 2
27	.thumb
28#endif
29
30@ int __divmodsi4(int divident, int divisor, int *remainder)
31@   Calculate the quotient and remainder of the (signed) division.  The return
32@   value is the quotient, the remainder is placed in the variable.
33
34	.p2align 3
35DEFINE_COMPILERRT_FUNCTION(__divmodsi4)
36#if __ARM_ARCH_EXT_IDIV__
37	tst     r1, r1
38	beq     LOCAL_LABEL(divzero)
39	mov 	r3, r0
40	sdiv	r0, r3, r1
41	mls 	r1, r0, r1, r3
42	str 	r1, [r2]
43	bx  	lr
44LOCAL_LABEL(divzero):
45	mov     r0, #0
46	bx      lr
47#else
48    ESTABLISH_FRAME
49//  Set aside the sign of the quotient and modulus, and the address for the
50//  modulus.
51    eor     r4,     r0, r1
52    mov     r5,     r0
53    mov     r6,     r2
54//  Take the absolute value of a and b via abs(x) = (x^(x >> 31)) - (x >> 31).
55    eor     ip,     r0, r0, asr #31
56    eor     lr,     r1, r1, asr #31
57    sub     r0,     ip, r0, asr #31
58    sub     r1,     lr, r1, asr #31
59//  Unsigned divmod:
60    bl      SYMBOL_NAME(__udivmodsi4)
61//  Apply the sign of quotient and modulus
62    ldr     r1,    [r6]
63    eor     r0,     r0, r4, asr #31
64    eor     r1,     r1, r5, asr #31
65    sub     r0,     r0, r4, asr #31
66    sub     r1,     r1, r5, asr #31
67    str     r1,    [r6]
68    CLEAR_FRAME_AND_RETURN
69#endif
70END_COMPILERRT_FUNCTION(__divmodsi4)
71