xref: /minix3/sys/arch/i386/conf/stand.ldscript (revision 0a6a1f1d05b60e214de2f05a7310ddd1f0e590e7)

/*	$NetBSD: stand.ldscript,v 1.5 2015/08/22 23:49:54 uebayasi Exp $	*/

OUTPUT_FORMAT("elf32-i386-minix", "elf32-i386-minix",
	      "elf32-i386-minix")
OUTPUT_ARCH(i386)
ENTRY(_start)
SECTIONS
{
  /* Read-only sections, merged into text segment: */
  .text :
  {
    *(.text)
    *(.text.*)
    *(.stub)
  }
  _etext = . ;
  PROVIDE (etext = .) ;

  .rodata :
  {
    *(.rodata)
    *(.rodata.*)
  }

  __data_start = . ;
  .data :
  {
    *(.data)
  }
  .data.cacheline_aligned :
  {
    *(.data.cacheline_aligned)
  }
  .data.read_mostly :
  {
    *(.data.read_mostly)
  }
  _edata = . ;
  PROVIDE (edata = .) ;
  __bss_start = . ;
  .bss :
  {
    *(.bss)
    *(.bss.*)
    *(COMMON)
    . = ALIGN(32 / 8);
  }
  . = ALIGN(32 / 8);
  _end = . ;
  PROVIDE (end = .) ;
  /DISCARD/ : {
    *(.eh_frame_hdr)
    *(.eh_frame)
    *(.note.netbsd.ident)
  }
}
SECTIONS
{
  .text :
  AT (ADDR(.text) & 0x0fffffff)
  {
    *(.text)
  } =0
}