xref: /csrg-svn/usr.sbin/sendmail/cf/m4/cf.m4 (revision 68840) 
1divert(0)dnl
2#
3# Copyright (c) 1983, 1995 Eric P. Allman
4# Copyright (c) 1988, 1993
5#	The Regents of the University of California.  All rights reserved.
6#
7# %sccs.include.redist.sh%
8#
9
10
11######################################################################
12######################################################################
13#####
14#####		SENDMAIL CONFIGURATION FILE
15#####
16define(`TEMPFILE', maketemp(/tmp/cfXXXXXX))dnl
17syscmd(sh ../sh/makeinfo.sh > TEMPFILE)dnl
18include(TEMPFILE)dnl
19syscmd(rm -f TEMPFILE)dnl
20#####
21######################################################################
22######################################################################
23
24divert(-1)
25
26changecom()
27undefine(`format')
28undefine(`hpux')
29ifdef(`pushdef', `',
30	`errprint(`You need a newer version of M4, at least as new as
31System V or GNU')
32	include(NoSuchFile)')
33define(`PUSHDIVERT', `pushdef(`__D__', divnum)divert($1)')
34define(`POPDIVERT', `divert(__D__)popdef(`__D__')')
35define(`OSTYPE',
36	`PUSHDIVERT(-1)
37	ifdef(`__OSTYPE__', `errprint(`duplicate OSTYPE')')
38	define(`__OSTYPE__', $1)
39	define(`_ARG_', $2)
40	include(../ostype/$1.m4)
41	POPDIVERT`'')
42define(`MAILER',
43`ifdef(`_MAILER_$1_', `dnl`'',
44`define(`_MAILER_$1_', `')PUSHDIVERT(7)include(../mailer/$1.m4)POPDIVERT`'')')
45define(`DOMAIN', `PUSHDIVERT(-1)define(`_ARG_', $2)include(../domain/$1.m4)POPDIVERT`'')
46define(`FEATURE', `PUSHDIVERT(-1)define(`_ARG_', $2)include(../feature/$1.m4)POPDIVERT`'')
47define(`HACK', `PUSHDIVERT(-1)define(`_ARG_', $2)include(../hack/$1.m4)POPDIVERT`'')
48define(`VERSIONID', ``#####  $1  #####'')
49define(`LOCAL_RULE_0', `divert(3)')
50define(`LOCAL_RULE_1',
51`divert(9)dnl
52#######################################
53###  Ruleset 1 -- Sender Rewriting  ###
54#######################################
55
56S1
57')
58define(`LOCAL_RULE_2',
59`divert(9)dnl
60##########################################
61###  Ruleset 2 -- Recipient Rewriting  ###
62##########################################
63
64S2
65')
66define(`LOCAL_RULE_3', `divert(2)')
67define(`LOCAL_CONFIG', `divert(6)')
68define(`LOCAL_NET_CONFIG', `define(`_LOCAL_RULES_', 1)divert(1)')
69define(`DOTTED_USER',
70	`ifdef(`__DOTTED_USER_LIST__',
71		`define(`__DOTTED_USER_LIST__', __DOTTED_USER_LIST__
72CD $1)',
73		`define(`__DOTTED_USER_LIST__', CD $1)')')
74define(`UUCPSMTP', `R DOL(*) < @ $1 .UUCP > DOL(*)	DOL(1) < @ $2 > DOL(2)')
75define(`CONCAT', `$1$2$3$4$5$6$7')
76define(`DOL', ``$'$1')
77define(`SITECONFIG',
78`CONCAT(D, $3, $2)
79define(`_CLASS_$3_', `')dnl
80ifelse($3, U, Cw$2 $2.UUCP, `dnl')
81define(`SITE', `ifelse(CONCAT($'2`, $3), SU,
82		CONCAT(CY, $'1`),
83		CONCAT(C, $3, $'1`))')
84sinclude(../siteconfig/$1.m4)')
85define(`EXPOSED_USER', `PUSHDIVERT(5)CE$1
86POPDIVERT`'dnl')
87define(`LOCAL_USER', `PUSHDIVERT(5)CL$1
88POPDIVERT`'dnl')
89define(`MASQUERADE_AS', `define(`MASQUERADE_NAME', $1)')
90
91m4wrap(`include(`../m4/proto.m4')')
92
93# set up default values for options
94define(`confMAILER_NAME', ``MAILER-DAEMON'')
95define(`confFROM_LINE', `From $g  $d')
96define(`confOPERATORS', `.:%@!^/[]+')
97define(`confSMTP_LOGIN_MSG', `$j Sendmail $v/$Z; $b')
98define(`confRECEIVED_HEADER', `$?sfrom $s $.$?_($?s$|from $.$_) $.by $j ($v/$Z)$?r with $r$. id $i$?u for $u$.; $b')
99define(`confSEVEN_BIT_INPUT', `False')
100define(`confEIGHT_BIT_HANDLING', `pass8')
101define(`confALIAS_WAIT', `10')
102define(`confMIN_FREE_BLOCKS', `100')
103define(`confBLANK_SUB', `.')
104define(`confCON_EXPENSIVE', `False')
105define(`confDELIVERY_MODE', `background')
106define(`confTEMP_FILE_MODE', `0600')
107define(`confMCI_CACHE_SIZE', `2')
108define(`confMCI_CACHE_TIMEOUT', `5m')
109define(`confUSE_ERRORS_TO', `False')
110define(`confLOG_LEVEL', `9')
111define(`confCHECK_ALIASES', `True')
112define(`confOLD_STYLE_HEADERS', `True')
113define(`confPRIVACY_FLAGS', `authwarnings')
114define(`confSAFE_QUEUE', `True')
115define(`confMESSAGE_TIMEOUT', `5d/4h')
116define(`confTIME_ZONE', `USE_SYSTEM')
117define(`confDEF_USER_ID', `1:1')
118define(`confCW_FILE', `/etc/sendmail.cw')
119define(`confMIME_FORMAT_ERRORS', `True')
120define(`confFORWARD_PATH', `$z/.forward.$w:$z/.forward')
121
122divert(0)dnl
123VERSIONID(`@(#)cf.m4	8.16 (Berkeley) 04/21/95')
124