xref: /llvm-project/mlir/test/Integration/Dialect/Vector/CPU/gather.mlir (revision eb206e9ea84eff0a0596fed2de8316d924f946d1)
1// RUN: mlir-opt %s -test-lower-to-llvm  | \
2// RUN: mlir-runner -e entry -entry-point-result=void \
3// RUN:   -shared-libs=%mlir_c_runner_utils | \
4// RUN: FileCheck %s
5
6func.func @gather8(%base: memref<?xf32>, %indices: vector<8xi32>,
7              %mask: vector<8xi1>, %pass_thru: vector<8xf32>) -> vector<8xf32> {
8  %c0 = arith.constant 0: index
9  %g = vector.gather %base[%c0][%indices], %mask, %pass_thru
10    : memref<?xf32>, vector<8xi32>, vector<8xi1>, vector<8xf32> into vector<8xf32>
11  return %g : vector<8xf32>
12}
13
14func.func @entry() {
15  // Set up memory.
16  %c0 = arith.constant 0: index
17  %c1 = arith.constant 1: index
18  %c10 = arith.constant 10: index
19  %A = memref.alloc(%c10) : memref<?xf32>
20  scf.for %i = %c0 to %c10 step %c1 {
21    %i32 = arith.index_cast %i : index to i32
22    %fi = arith.sitofp %i32 : i32 to f32
23    memref.store %fi, %A[%i] : memref<?xf32>
24  }
25
26  // Set up idx vector.
27  %i0 = arith.constant 0: i32
28  %i1 = arith.constant 1: i32
29  %i2 = arith.constant 2: i32
30  %i3 = arith.constant 3: i32
31  %i4 = arith.constant 4: i32
32  %i5 = arith.constant 5: i32
33  %i6 = arith.constant 6: i32
34  %i9 = arith.constant 9: i32
35  %0 = vector.broadcast %i0 : i32 to vector<8xi32>
36  %1 = vector.insert %i6, %0[1] : i32 into vector<8xi32>
37  %2 = vector.insert %i1, %1[2] : i32 into vector<8xi32>
38  %3 = vector.insert %i3, %2[3] : i32 into vector<8xi32>
39  %4 = vector.insert %i5, %3[4] : i32 into vector<8xi32>
40  %5 = vector.insert %i4, %4[5] : i32 into vector<8xi32>
41  %6 = vector.insert %i9, %5[6] : i32 into vector<8xi32>
42  %idx = vector.insert %i2, %6[7] : i32 into vector<8xi32>
43
44  // Set up pass thru vector.
45  %u = arith.constant -7.0: f32
46  %pass = vector.broadcast %u : f32 to vector<8xf32>
47
48  // Set up masks.
49  %t = arith.constant 1: i1
50  %none = vector.constant_mask [0] : vector<8xi1>
51  %all = vector.constant_mask [8] : vector<8xi1>
52  %some = vector.constant_mask [4] : vector<8xi1>
53  %more = vector.insert %t, %some[7] : i1 into vector<8xi1>
54
55  //
56  // Gather tests.
57  //
58
59  %g1 = call @gather8(%A, %idx, %all, %pass)
60    : (memref<?xf32>, vector<8xi32>, vector<8xi1>, vector<8xf32>)
61    -> (vector<8xf32>)
62  vector.print %g1 : vector<8xf32>
63  // CHECK: ( 0, 6, 1, 3, 5, 4, 9, 2 )
64
65  %g2 = call @gather8(%A, %idx, %none, %pass)
66    : (memref<?xf32>, vector<8xi32>, vector<8xi1>, vector<8xf32>)
67    -> (vector<8xf32>)
68  vector.print %g2 : vector<8xf32>
69  // CHECK: ( -7, -7, -7, -7, -7, -7, -7, -7 )
70
71  %g3 = call @gather8(%A, %idx, %some, %pass)
72    : (memref<?xf32>, vector<8xi32>, vector<8xi1>, vector<8xf32>)
73    -> (vector<8xf32>)
74  vector.print %g3 : vector<8xf32>
75  // CHECK: ( 0, 6, 1, 3, -7, -7, -7, -7 )
76
77  %g4 = call @gather8(%A, %idx, %more, %pass)
78    : (memref<?xf32>, vector<8xi32>, vector<8xi1>, vector<8xf32>)
79    -> (vector<8xf32>)
80  vector.print %g4 : vector<8xf32>
81  // CHECK: ( 0, 6, 1, 3, -7, -7, -7, 2 )
82
83  %g5 = call @gather8(%A, %idx, %all, %pass)
84    : (memref<?xf32>, vector<8xi32>, vector<8xi1>, vector<8xf32>)
85    -> (vector<8xf32>)
86  vector.print %g5 : vector<8xf32>
87  // CHECK: ( 0, 6, 1, 3, 5, 4, 9, 2 )
88
89  memref.dealloc %A : memref<?xf32>
90  return
91}
92