xref: /netbsd-src/sys/arch/hppa/conf/ld.script (revision c0e6eb15f5e658347879c2fd8a62731685a91e28) 
1/*	$NetBSD: ld.script,v 1.2 2015/08/22 23:47:34 uebayasi Exp $	*/
2
3/* 	$OpenBSD: ld.script,v 1.7 1999/12/17 07:02:38 mickey Exp $	*/
4
5OUTPUT_FORMAT("elf32-hppa-netbsd")
6OUTPUT_ARCH(hppa)
7ENTRY(start)
8SECTIONS
9{
10	. = + SIZEOF_HEADERS;
11	.text :
12	{
13		kernel_text = . ;
14		*(.text) *(.text.*)
15		*(.reginfo)
16		*(.init)
17		*(.stub)
18		/* .gnu.warning sections are handled specially by elf32.em.  */
19		*(.gnu.warning)
20		. = ALIGN(4096);
21		etext = ABSOLUTE(.);
22	} = 0x08000240 /* nop filled */
23
24	__rodata_start = ABSOLUTE(.);
25	.rodata	:
26	{
27		*(.rodata) *(.rodata.*) *(.rodata1)
28		. = ALIGN(8);
29	} = 0
30	__unwind_start = .;
31	.PARISC.unwind   : { *(.PARISC.unwind) }
32	__unwind_end = .;
33
34	/* Place (orphaned) link_sets */
35	. = .;
36
37	/* Align __rodata_end to page boundary */
38	. = ALIGN(4096);
39	__rodata_end = ABSOLUTE(.);
40
41	. = ALIGN(0x200000);
42	__data_start = ABSOLUTE(.);
43	.data  :
44	{
45		$global$ = . ;
46		. += 4;
47		*(.data)
48		CONSTRUCTORS
49		. = ALIGN(4096);
50		edata = ABSOLUTE(.);
51	} = 0
52
53	__bss_start = ABSOLUTE(.);
54	/* .sbss	: { *(.sbss) *(.scommon) } */
55	.bss :
56	{
57		*(.dynbss) *(.bss)
58		*(COMMON) *($COMMON$)
59		. = ALIGN(4096);
60	}
61	end = ABSOLUTE(.);
62	.note.netbsd.ident :
63	{
64		KEEP(*(.note.netbsd.ident));
65	}
66}
67