xref: /llvm-project/mlir/test/Dialect/MemRef/subview.mlir (revision 6dc8de7a0abc7df8295273694fd9b951ed33708f) 
1// RUN: mlir-opt %s | mlir-opt | FileCheck %s
2// RUN: mlir-opt %s --mlir-print-op-generic | mlir-opt | FileCheck %s
3
4// CHECK-DAG: #[[$BASE_MAP1:map[0-9]*]] = affine_map<(d0)[s0] -> (d0 + s0)>
5// CHECK-DAG: #[[$SUBVIEW_MAP1:map[0-9]*]] = affine_map<(d0)[s0, s1] -> (d0 * s1 + s0)>
6// CHECK-DAG: #[[$SUBVIEW_MAP11:map[0-9]*]] = affine_map<() -> (4)>
7// CHECK-DAG: #[[$SUBVIEW_MAP12:map[0-9]*]] = affine_map<()[s0] -> (s0)>
8
9// CHECK-LABEL: func @memref_subview(%arg0
10func.func @memref_subview(%arg0 : index, %arg1 : index, %arg2 : index) {
11  // CHECK-DAG: %[[c0:.*]] = arith.constant 0 : index
12  // CHECK-DAG: %[[c1:.*]] = arith.constant 1 : index
13  %c0 = arith.constant 0 : index
14  %c1 = arith.constant 1 : index
15
16  %0 = memref.alloc() : memref<8x16x4xf32, strided<[64, 4, 1], offset: 0>>
17  // CHECK: subview %{{.*}}[%[[c0]], %[[c0]], %[[c0]]] [%{{.*}}, %{{.*}}, %{{.*}}] [%[[c1]], %[[c1]], %[[c1]]] :
18  // CHECK-SAME: memref<8x16x4xf32, strided<[64, 4, 1]>>
19  // CHECK-SAME: to memref<?x?x?xf32, strided<[?, ?, ?], offset: ?>>
20  %1 = memref.subview %0[%c0, %c0, %c0][%arg0, %arg1, %arg2][%c1, %c1, %c1]
21    : memref<8x16x4xf32, strided<[64, 4, 1], offset: 0>> to
22      memref<?x?x?xf32, strided<[?, ?, ?], offset: ?>>
23
24  %2 = memref.alloc()[%arg2] : memref<64xf32, affine_map<(d0)[s0] -> (d0 + s0)>>
25  // CHECK: memref.subview %{{.*}}[%[[c1]]] [%{{.*}}] [%[[c1]]] :
26  // CHECK-SAME: memref<64xf32, #[[$BASE_MAP1]]>
27  // CHECK-SAME: to memref<?xf32, #[[$SUBVIEW_MAP1]]>
28  %3 = memref.subview %2[%c1][%arg0][%c1]
29    : memref<64xf32, affine_map<(d0)[s0] -> (d0 + s0)>> to
30      memref<?xf32, affine_map<(d0)[s0, s1] -> (d0 * s1 + s0)>>
31
32  %4 = memref.alloc() : memref<64x22xf32, strided<[22, 1]>>
33  // CHECK: memref.subview %{{.*}}[%[[c0]], %[[c1]]] [%{{.*}}, %{{.*}}] [%[[c1]], %[[c0]]] :
34  // CHECK-SAME: memref<64x22xf32, strided<[22, 1]>>
35  // CHECK-SAME: to memref<?x?xf32, strided<[?, ?], offset: ?>>
36  %5 = memref.subview %4[%c0, %c1][%arg0, %arg1][%c1, %c0]
37    : memref<64x22xf32, strided<[22, 1], offset: 0>> to
38      memref<?x?xf32, strided<[?, ?], offset: ?>>
39
40  // CHECK: memref.subview %{{.*}}[0, 2, 0] [4, 4, 4] [1, 1, 1] :
41  // CHECK-SAME: memref<8x16x4xf32, strided<[64, 4, 1]>>
42  // CHECK-SAME: to memref<4x4x4xf32, strided<[64, 4, 1], offset: 8>>
43  %6 = memref.subview %0[0, 2, 0][4, 4, 4][1, 1, 1]
44    : memref<8x16x4xf32, strided<[64, 4, 1], offset: 0>> to
45      memref<4x4x4xf32, strided<[64, 4, 1], offset: 8>>
46
47  %7 = memref.alloc(%arg1, %arg2) : memref<?x?xf32>
48  // CHECK: memref.subview {{%.*}}[0, 0] [4, 4] [1, 1] :
49  // CHECK-SAME: memref<?x?xf32>
50  // CHECK-SAME: to memref<4x4xf32, strided<[?, 1]>>
51  %8 = memref.subview %7[0, 0][4, 4][1, 1]
52    : memref<?x?xf32> to memref<4x4xf32, strided<[?, 1]>>
53
54  %9 = memref.alloc() : memref<16x4xf32>
55  // CHECK: memref.subview {{%.*}}[{{%.*}}, {{%.*}}] [4, 4] [{{%.*}}, {{%.*}}] :
56  // CHECK-SAME: memref<16x4xf32>
57  // CHECK-SAME: to memref<4x4xf32, strided<[?, ?], offset: ?>>
58  %10 = memref.subview %9[%arg1, %arg1][4, 4][%arg2, %arg2]
59    : memref<16x4xf32> to memref<4x4xf32, strided<[?, ?], offset: ?>>
60
61  // CHECK: memref.subview {{%.*}}[{{%.*}}, {{%.*}}] [4, 4] [2, 2] :
62  // CHECK-SAME: memref<16x4xf32>
63  // CHECK-SAME: to memref<4x4xf32, strided<[8, 2], offset: ?>>
64  %11 = memref.subview %9[%arg1, %arg2][4, 4][2, 2]
65    : memref<16x4xf32> to memref<4x4xf32, strided<[8, 2], offset: ?>>
66
67  %12 = memref.alloc() : memref<1x9x1x4x1xf32, strided<[36, 36, 4, 4, 1]>>
68  // CHECK: memref.subview
69  // CHECK-SAME: [1, 9, 1, 4, 1]
70  // CHECK-SAME: memref<1x9x1x4x1xf32, strided<[36, 36, 4, 4, 1]>> to memref<9x4xf32, strided<[?, ?], offset: ?>>
71  %13 = memref.subview %12[%arg1, %arg1, %arg1, %arg1, %arg1][1, 9, 1, 4, 1][%arg2, %arg2, %arg2, %arg2, %arg2] : memref<1x9x1x4x1xf32, strided<[36, 36, 4, 4, 1], offset: 0>> to memref<9x4xf32, strided<[?, ?], offset: ?>>
72  // CHECK: memref.subview
73  // CHECK-SAME: [1, 9, 1, 4, 1]
74  // CHECK-SAME: memref<1x9x1x4x1xf32, strided<[36, 36, 4, 4, 1]>> to memref<1x9x4xf32, strided<[?, ?, ?], offset: ?>>
75  %14 = memref.subview %12[%arg1, %arg1, %arg1, %arg1, %arg1][1, 9, 1, 4, 1][%arg2, %arg2, %arg2, %arg2, %arg2] : memref<1x9x1x4x1xf32, strided<[36, 36, 4, 4, 1], offset: 0>> to memref<1x9x4xf32, strided<[?, ?, ?], offset: ?>>
76
77  %15 = memref.alloc(%arg1, %arg2)[%c0, %c1, %arg1, %arg0, %arg0, %arg2, %arg2] : memref<1x?x5x1x?x1xf32, strided<[?, ?, ?, ?, ?, ?], offset: ?>>
78  // CHECK: memref.subview %{{.*}}[0, 0, 0, 0, 0, 0] [1, %{{.*}}, 5, 1, %{{.*}}, 1] [1, 1, 1, 1, 1, 1]  :
79  // CHECK-SAME: memref<1x?x5x1x?x1xf32, strided<[?, ?, ?, ?, ?, ?], offset: ?>> to memref<?x5x?xf32, strided<[?, ?, ?], offset: ?>>
80  %16 = memref.subview %15[0, 0, 0, 0, 0, 0][1, %arg1, 5, 1, %arg2, 1][1, 1, 1, 1, 1, 1] : memref<1x?x5x1x?x1xf32, strided<[?, ?, ?, ?, ?, ?], offset: ?>> to memref<?x5x?xf32, strided<[?, ?, ?], offset: ?>>
81  // CHECK: memref.subview %{{.*}}[%{{.*}}, %{{.*}}, %{{.*}}, %{{.*}}, %{{.*}}, %{{.*}}] [1, %{{.*}}, 5, 1, %{{.*}}, 1] [1, 1, 1, 1, 1, 1]  :
82  // CHECK-SAME: memref<1x?x5x1x?x1xf32, strided<[?, ?, ?, ?, ?, ?], offset: ?>> to memref<?x5x?x1xf32, strided<[?, ?, ?, ?], offset: ?>>
83  %17 = memref.subview %15[%arg1, %arg1, %arg1, %arg1, %arg1, %arg1][1, %arg1, 5, 1, %arg2, 1][1, 1, 1, 1, 1, 1] :  memref<1x?x5x1x?x1xf32, strided<[?, ?, ?, ?, ?, ?], offset: ?>> to memref<?x5x?x1xf32, strided<[?, ?, ?, ?], offset: ?>>
84
85  %18 = memref.alloc() : memref<1x8xf32>
86  // CHECK: memref.subview %{{.*}}[0, 0] [1, 8] [1, 1]  : memref<1x8xf32> to memref<8xf32>
87  %19 = memref.subview %18[0, 0][1, 8][1, 1] : memref<1x8xf32> to memref<8xf32>
88
89  %20 = memref.alloc() : memref<8x16x4xf32>
90  // CHECK: memref.subview %{{.*}}[0, 0, 0] [1, 16, 4] [1, 1, 1]  : memref<8x16x4xf32> to memref<16x4xf32>
91  %21 = memref.subview %20[0, 0, 0][1, 16, 4][1, 1, 1] : memref<8x16x4xf32> to memref<16x4xf32>
92
93  %22 = memref.subview %20[3, 4, 2][1, 6, 3][1, 1, 1] : memref<8x16x4xf32> to memref<6x3xf32, strided<[4, 1], offset: 210>>
94
95  %23 = memref.alloc() : memref<f32>
96  %78 = memref.subview %23[] [] []  : memref<f32> to memref<f32>
97
98  /// Subview with only leading operands.
99  %24 = memref.alloc() : memref<5x3xf32>
100  // CHECK: memref.subview %{{.*}}[2, 0] [3, 3] [1, 1] : memref<5x3xf32> to memref<3x3xf32, strided<[3, 1], offset: 6>>
101  %25 = memref.subview %24[2, 0][3, 3][1, 1]: memref<5x3xf32> to memref<3x3xf32, strided<[3, 1], offset: 6>>
102
103  /// Rank-reducing subview with only leading operands.
104  // CHECK: memref.subview %{{.*}}[1, 0] [1, 3] [1, 1] : memref<5x3xf32> to memref<3xf32, strided<[1], offset: 3>>
105  %26 = memref.subview %24[1, 0][1, 3][1, 1]: memref<5x3xf32> to memref<3xf32, strided<[1], offset: 3>>
106
107  // Corner-case of 0-D rank-reducing subview with an offset.
108  // CHECK: memref.subview %{{.*}}[1, 1] [1, 1] [1, 1] : memref<5x3xf32> to memref<f32, #[[$SUBVIEW_MAP11]]>
109  %27 = memref.subview %24[1, 1] [1, 1] [1, 1] : memref<5x3xf32> to memref<f32, affine_map<() -> (4)>>
110
111  // CHECK: memref.subview %{{.*}}[%{{.*}}, 1] [1, 1] [1, 1] : memref<5x3xf32> to memref<f32, #[[$SUBVIEW_MAP12]]>
112  %28 = memref.subview %24[%arg0, 1] [1, 1] [1, 1] : memref<5x3xf32> to memref<f32, affine_map<()[s0] -> (s0)>>
113
114  // CHECK: memref.subview %{{.*}}[0, %{{.*}}] [%{{.*}}, 1] [1, 1] : memref<?x?xf32> to memref<?xf32, #[[$SUBVIEW_MAP1]]>
115  %a30 = memref.alloc(%arg0, %arg0) : memref<?x?xf32>
116  %30 = memref.subview %a30[0, %arg1][%arg2, 1][1, 1] : memref<?x?xf32> to memref<?xf32, affine_map<(d0)[s0, s1] -> (d0 * s1 + s0)>>
117
118  %c8 = arith.constant 8 : index
119  %a40 = memref.alloc() : memref<16x16xf32>
120  // CHECK: memref.subview
121  %40 = memref.subview %a40[%c8, 8][8, 8][1, 1]  :
122    memref<16x16xf32> to memref<8x8xf32, affine_map<(d0, d1)[s0] -> (d0 * 16 + d1 + s0)>>
123
124  return
125}
126
127