xref: /openbsd-src/gnu/llvm/llvm/utils/gn/secondary/llvm/lib/Target/targets.gni (revision d415bd752c734aee168c4ee86ff32e8cc249eb16) 
1import("//llvm/utils/gn/build/toolchain/compiler.gni")
2
3declare_args() {
4  # The target archs LLVM should support. Defaults to the host arch.
5  # Set to a list, e.g. `llvm_targets_to_build = [ "X86", "ARM" ]`,
6  # or to the string "all" to get all known targets.
7  llvm_targets_to_build = "host"
8}
9
10# FIXME: Port the remaining targets.
11llvm_all_stable_targets = [
12  "AArch64",
13  "AMDGPU",
14  "ARM",
15  "AVR",
16  "BPF",
17  "Hexagon",
18  "Lanai",
19  "Mips",
20  "NVPTX",
21  "PowerPC",
22  "RISCV",
23  "Sparc",
24  "SystemZ",
25  "WebAssembly",
26  "X86",
27]
28
29llvm_all_experimental_targets = [ "LoongArch" ]
30
31llvm_all_targets = llvm_all_stable_targets + llvm_all_experimental_targets
32
33# FIXME: This should be based off target_cpu once cross compiles work.
34if (host_cpu == "arm64") {
35  native_target = "AArch64"
36} else if (host_cpu == "arm") {
37  native_target = "ARM"
38} else if (host_cpu == "ppc" || host_cpu == "ppc64") {
39  native_target = "PowerPC"
40} else if (host_cpu == "x86" || host_cpu == "x64") {
41  native_target = "X86"
42} else {
43  assert(false, "add your host_cpu above")
44}
45
46if (llvm_targets_to_build == "host") {
47  llvm_targets_to_build = [ native_target ]
48} else if (llvm_targets_to_build == "all") {
49  llvm_targets_to_build = llvm_all_stable_targets
50} else if (llvm_targets_to_build == "experimental") {
51  llvm_targets_to_build = llvm_all_targets
52}
53
54# Validate that llvm_targets_to_build is set to a list of valid targets,
55# and remember which targets are built where needed (for conditionally-built
56# unittest targets).
57llvm_build_AArch64 = false
58llvm_build_AMDGPU = false
59llvm_build_ARM = false
60llvm_build_BPF = false
61llvm_build_LoongArch = false
62llvm_build_Mips = false
63llvm_build_PowerPC = false
64llvm_build_SystemZ = false
65llvm_build_WebAssembly = false
66llvm_build_X86 = false
67llvm_build_native = false
68foreach(target, llvm_targets_to_build) {
69  if (target == native_target) {
70    llvm_build_native = true
71  }
72  if (target == "AArch64") {
73    llvm_build_AArch64 = true
74  } else if (target == "AMDGPU") {
75    llvm_build_AMDGPU = true
76  } else if (target == "ARM") {
77    llvm_build_ARM = true
78  } else if (target == "BPF") {
79    llvm_build_BPF = true
80  } else if (target == "LoongArch") {
81    llvm_build_LoongArch = true
82  } else if (target == "Mips") {
83    llvm_build_Mips = true
84  } else if (target == "PowerPC") {
85    llvm_build_PowerPC = true
86  } else if (target == "SystemZ") {
87    llvm_build_SystemZ = true
88  } else if (target == "WebAssembly") {
89    llvm_build_WebAssembly = true
90  } else if (target == "X86") {
91    llvm_build_X86 = true
92  } else if (target == "AVR" || target == "Hexagon" || target == "Lanai" ||
93             target == "NVPTX" || target == "RISCV" || target == "Sparc" ||
94             target == "SystemZ") {
95    # Nothing to do.
96  } else {
97    all_targets_string = ""
98    foreach(target, llvm_all_targets) {
99      all_targets_string += "$0x0a    " + target
100    }
101    assert(false, "Unknown target '$target' in llvm_targets_to_build. " +
102                      "Known targets:" + all_targets_string)
103  }
104}
105
106supported_android_toolchains = []
107
108if (android_ndk_path != "") {
109  if (llvm_build_AArch64) {
110    supported_android_toolchains +=
111        [ "//llvm/utils/gn/build/toolchain:stage2_android_aarch64" ]
112  }
113  if (llvm_build_ARM) {
114    supported_android_toolchains +=
115        [ "//llvm/utils/gn/build/toolchain:stage2_android_arm" ]
116  }
117}
118